sub osterng( $ ){

    #
    # Ostern: Gauß (vgl Lichtenberg 1997), Quelle PTB Braunschweig
    #         s/a https://de.wikipedia.org/wiki/Gau%C3%9Fsche_Osterformel
    #

    # 
    # Argument: Jahr
    #

    my $year = shift;

    my $k = int( $year/100 );                         # Säkulum

    my $s = int( ($k*3 + 3) / 4 );

    my $m = 15 + int( $s ) - int( ($k*8 + 13) / 25 ); # Mondschaltung

       $s = 2 - $s;                                   # Sonnenschaltung

    my $a = $year % 19;                               # Mondzyklus

    my $d = ( 19*$a + $m ) % 30;                      # Frühlingsvollmond

    my $r = int( $d/29 ) + ( int( $d/28 ) - int( $d/29 ) ) * int( $a/11 );

    #
    # og: Ostervollmond März: Monat 1, Tag 14 im Mondkalender (Nisanu)
    #

    my $og = 21 + $d - $r;

    #
    # sz: erster Sonntag im März
    # oe: Ostergrenze (og) bis Ostersonntag: Osterentfernung 
    #

    my $sz = 7 - ( $year + int($year/4) + $s ) % 7;
    my $oe = 7 - ( $og-$sz ) % 7;

    #
    # og + oe: Ostersonntag als Märzdatum, 32 entspr Apr-01 ..
    #

    $d = $og + $oe;
    $m = $d < 32 ? 2 : 3;                   # Jan 0 .. Dez 11
    $d = $d < 32 ? $d : $d - 31; 

    return $d, $m;
 
}

# ----------------------------------------------------------------------